# Machinechat with Arduino MKR1000

**URL:** <https://forum.digikey.com/t/machinechat-with-arduino-mkr1000/9470>\
**Category:** machinechat\
**Created:** [October 14, 2020, 5:22pm UTC](https://forum.digikey.com/t/machinechat-with-arduino-mkr1000/9470 "2020-10-14T17:22:40Z")\
**Posts on this page:** 1\
**Page:** 1

<div class="post-metadata">

**Author:** ![RobertCNelson](https://sea2.discourse-cdn.com/digikey/user_avatar/forum.digikey.com/robertcnelson/32/12_2.png) [@RobertCNelson](https://forum.digikey.com/u/RobertCNelson)\
**Post date:** [October 14, 2020, 5:22pm UTC](https://forum.digikey.com/t/machinechat-with-arduino-mkr1000/9470/1 "2020-10-14T17:22:40Z")

</div>

Software:

- [JEDI One](https://www.digikey.com/short/znpb2w)
- [Arduino](https://www.arduino.cc/)

Project Parts:

- [ARDUINO MKR1000](https://www.digikey.com/en/products/detail/arduino/ABX00004/6595547)
- [ARDUINO MKR1000 BRD WITH HEADERS MOUNTED](https://www.digikey.com/en/products/detail/arduino/ABX00011/6829064)

Add these libraries thru Arduino’s Library Manager:

- [ArduinoHttpClient](https://github.com/arduino-libraries/ArduinoHttpClient)
- [ArduinoJson](https://arduinojson.org/)

_Full Source:_

```auto
#include <SPI.h>
#include <WiFi101.h>
#include "arduino_secrets.h" 
///////please enter your sensitive data in the Secret tab/arduino_secrets.h
char ssid[] = SECRET_SSID; // your network SSID (name)
char pass[] = SECRET_PASS; // your network password (use for WPA, or use as key for WEP)
int keyIndex = 0; // your network key Index number (needed only for WEP)

#include <ArduinoJson.h>
#include <ArduinoHttpClient.h>

// Create a unique ID for the data from each device running this code
const char* jediID = "Arduino_MKR1000";

char serverAddress[] = "192.168.3.104";
int port = 8100;

// Initialize the Ethernet client library
WiFiClient wlan;
HttpClient client = HttpClient(wlan, serverAddress, port);
int status = WL_IDLE_STATUS;

void setup() {
  //Initialize serial and wait for port to open:
  Serial.begin(115200);
  while (!Serial) {
    ; // wait for serial port to connect. Needed for native USB port only
  }

  // check for the presence of the shield:
  if (WiFi.status() == WL_NO_SHIELD) {
    Serial.println("WiFi shield not present");
    // don't continue:
    while (true);
  }

  // attempt to connect to WiFi network:
  while (status != WL_CONNECTED) {
    Serial.print("Attempting to connect to SSID: ");
    Serial.println(ssid);
    // Connect to WPA/WPA2 network. Change this line if using open or WEP network:
    status = WiFi.begin(ssid, pass);

    // wait 10 seconds for connection:
    delay(10000);
  }
  Serial.println("Connected to wifi");
  printWiFiStatus();
}

void loop() {
  String postData;

  //Fake Sensor Reading
  float Fake_Sensor_tempF = 78.8;

  Serial.print(" | Temp[F]: ");
  Serial.print(Fake_Sensor_tempF, 2);
  Serial.println(" |");

  StaticJsonDocument <200> doc;
  
  JsonObject context = doc.createNestedObject("context");
  context["target_id"] = String(jediID);

  JsonObject data = doc.createNestedObject("data");
  data["Fake_tempF"] = Fake_Sensor_tempF;

  serializeJson(doc, postData);

  //This prints the JSON to the serial monitor screen
  Serial.println(postData);
  
  if (status == WL_CONNECTED) {
    String contentType = "application/json";

    client.post("/v1/data/mc", contentType, postData);

    // read the status code and body of the response
    int statusCode = client.responseStatusCode();
    String response = client.responseBody();
  
    Serial.print("Status code: ");
    Serial.println(statusCode);
    Serial.print("Response: ");
    Serial.println(response);
  }

  delay(1000);
}

void printWiFiStatus() {
  // print the SSID of the network you're attached to:
  Serial.print("SSID: ");
  Serial.println(WiFi.SSID());

  // print your WiFi shield's IP address:
  IPAddress ip = WiFi.localIP();
  Serial.print("IP Address: ");
  Serial.println(ip);

  // print the received signal strength:
  long rssi = WiFi.RSSI();
  Serial.print("signal strength (RSSI):");
  Serial.print(rssi);
  Serial.println(" dBm");
}

```